@echo off

set toolWin=.\deploy\zip-tool-win.exe
set toolLinux=.\deploy\zip-tool-linux
@REM 服务器端工具路径
set remoteToolName=~/zip-tool-linux 
set user=username
set host=x.x.x.x
set passwd=passwd
set localDist=.\dist
set localZipName=.\dist.zip

@REM 修改以下设置，适配自己的项目
set remoteCWD=/path-to-your-program
set remoteDist=/path-to-your-program/dist
set remoteZipName=/path-to-your-program/dist.zip

@REM 前端生成最新部署文件，使用call，防止生成后关闭命令行窗口
call yarn run build || exit /B

@REM 压缩
%toolWin% -act zip ^
  -src %localDist% ^
  -dst %localZipName% || exit /B

@REM 发送工具包
%toolWin% -act scp ^
  -src %toolLinux% ^
  -dst %remoteToolName% ^
  -user %user% ^
  -host %host% ^
  -passwd %passwd% || exit /B

@REM 增加权限+清理目录
%toolWin% -act sh ^
  -cmd "chmod +x %remoteToolName% && cd %remoteCWD% && ls -alh && rm -rf ./dist/*" ^
  -user %user% ^
  -host %host% ^
  -passwd %passwd% || exit /B

@REM 发送部署文件
%toolWin% -act scp ^
  -src %localZipName% ^
  -dst %remoteZipName% ^
  -user %user% ^
  -host %host% ^
  -passwd %passwd% || exit /B

@REM 远端解压
%toolWin% -act sh ^
  -cmd "%remoteToolName% -act unzip -src %remoteZipName% -dst %remoteDist%" ^
  -user %user% ^
  -host %host% ^
  -passwd %passwd% || exit /B

@REM 远端部署脚本
%toolWin% -act sh ^
  -cmd "cd %remoteCWD% && ./easyfix-app-3-hr.sh easyfix-app-3-hr-auto" ^
  -user %user% ^
  -host %host% ^
  -passwd %passwd% || exit /B

PAUSE