terralang / terrac Goto Github PK

function (terra_module_directories)
	foreach (arg IN LISTS ARGN)
		list (APPEND TERRA_MODPATH "${arg}")
	endforeach ()
	set (TERRA_MODPATH "${TERRA_MODPATH}" PARENT_SCOPE)
endfunction ()

function (add_terra_executable ARG_NAME)
	if (ARGC LESS 2)
		message (FATAL_ERROR "add_terra_executable(name, ...) requires at least one source")
	endif ()

	get_property(dirs DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY INCLUDE_DIRECTORIES)
	foreach (DIR IN LISTS dirs)
		list (APPEND includedirs "-I")
		list (APPEND includedirs "${DIR}")
	endforeach ()
	foreach (modpath IN LISTS TERRA_MODPATH)
		list (APPEND includedirs "-m")
		list (APPEND includedirs "${modpath}")
	endforeach ()

	foreach (file IN LISTS ARGN)
		get_filename_component (ext "${file}" EXT)
		if (ext STREQUAL ".t")
			get_filename_component (fileabs "${file}" ABSOLUTE BASE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
			file (TO_CMAKE_PATH "${fileabs}" fileabssrc)
			file (RELATIVE_PATH filerel "${CMAKE_CURRENT_SOURCE_DIR}" "${fileabssrc}")
			get_filename_component (output "${filerel}" ABSOLUTE BASE_DIR "${CMAKE_CURRENT_BINARY_DIR}")
			get_filename_component (filedir "${fileabs}" DIRECTORY)

			message(STATUS "terra: ${output}.o")
			add_custom_command (
				OUTPUT "${output}.o"
				COMMAND "$<TARGET_FILE:terrac>" ARGS -I "${filedir}" -P "${CMAKE_CURRENT_BINARY_DIR}" -D "${output}.d" -o "${output}.o" ${includedirs} "${fileabs}"
				WORKING_DIRECTORY "${filedir}"
				MAIN_DEPENDENCY "${fileabs}"
				DEPFILE "${output}.d"
				COMMENT "Terra: ${output}.o"
				VERBATIM
				COMMAND_EXPAND_LISTS)

			list (APPEND link_sources "${output}.o")
		else ()
			list (APPEND compile_sources "${file}")
		endif ()
	endforeach ()

	list (LENGTH compile_sources compile_sources_count)
	if (compile_sources_count EQUAL 0)
		message (FATAL_ERROR "add_terra_executable(name, ...) requires at least one non-terra source file (I know, I know...)")
	endif ()

	list (LENGTH link_sources link_sources_count)

	add_executable ("${ARG_NAME}" ${compile_sources})
	if (link_sources_count GREATER 0)
		target_link_libraries ("${ARG_NAME}" ${link_sources})

		add_custom_target ("${ARG_NAME}__terra"
			DEPENDS "${link_sources}")

		add_dependencies ("${ARG_NAME}" "${ARG_NAME}__terra")
		add_dependencies ("${ARG_NAME}__terra" terrac)
	endif ()
endfunction ()