task wrapper(type: Wrapper) {
    gradleVersion = '4.9'
}

plugins {
    // ... other plugins ...
    id "edu.wpi.first.GradleRIO" version "2019.0.0-alpha-3"
}

deploy {
    targets {
        target('roborio', RoboRIO) {
            team = getTeamOrDefault(5333)
            // Other values can be edited through EmbeddedTools.
            // See https://github.com/JacisNonsense/EmbeddedTools#spec
        }
        // Other targets can be edited through EmbeddedTools.
        // See https://github.com/JacisNonsense/EmbeddedTools#spec
    }
    artifacts {
        // Setup a Java Artifact. Required for Java Users.
        artifact('myJava', FRCJavaArtifact) {
            targets << 'roborio'

            jvmArgs << '-Xmx=128m'      // Set more JVM Arguments. Optional.
            arguments << 'myCustomArgs' // The command-line arguments to launch your jar with. Optional.
            debug = getDebugOrDefault(false)                // Enable to enable java debugging on the RoboRIO. Default: false
            debugPort = 8348            // Set the debugging port. Default: 8348
            robotCommand = './myOtherProgram'       // Set the contents of robotCommand. Optional, usually created depending on above values.

            // Other values can be edited through EmbeddedTools.
            // See https://github.com/JacisNonsense/EmbeddedTools#spec
        }

        // Setup a C++ (Native) Artifact. Required for C++ (Native) Users
        artifact('myNative', FRCNativeArtifact) {
            targets << 'roborio'
            component = 'myFrcBinary'   // The name of the component you wish to build (required).

            arguments << 'myCustomArgs' // The command-line arguments to launch your jar with. Optional.
            debug = getDebugOrDefault(false)                // Enable to enable cpp debugging on the RoboRIO. Default: false
            debugPort = 8348            // Set the debugging port. Default: 8348
            robotCommand = './myOtherProgram'       // Set the contents of robotCommand. Optional, usually created depending on above values.

            // Other values can be edited through EmbeddedTools.
            // See https://github.com/JacisNonsense/EmbeddedTools#spec
        }
        // Other artifacts can be edited through EmbeddedTools.
        // See https://github.com/JacisNonsense/EmbeddedTools#spec
    }
}

// Set the versions of libraries to use. This is calculated for you based
// off known-stable versions for the current year, but you can modify
// them here if you so desire. This block is not required.
wpi {
    wpilibVersion = '...'
    ntcoreVersion = '...'
    opencvVersion = '...'
    cscoreVersion = '...'
    wpiutilVersion = '...'

    smartDashboardVersion = '...'
    shuffleboardVersion = '...'

    toolchainVersion = '...'
}

// Set the dependencies you want to use in your JAVA project.
// WPILib adds WPILibJ, NTCore, OpenCV, CSCore among others.
dependencies {
    compile wpilib()
}

// Java only. Setup your Jar File.
jar {
    // Compile a 'fat jar' (libraries included)
    from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    // Include your Manifest. Arguments are your Robot Main Class.
    manifest GradleRIOPlugin.javaManifest('test.myClass')
}

// Set up your Native (C++) projects. Not needed in Java.
model {
    components {
        myFrcBinary(NativeExecutableSpec) {
            targetPlatform 'roborio'
            sources.cpp {
                source {
                    srcDir 'src/main/cpp'
                }
            }
            // Add the libraries you wish to use in your NATIVE project.
            // WPILib adds WPILibJ, NTCore, OpenCV, CSCore among others.
            useLibrary(it, "wpilib")
        }
    }
}