Terraform module designed to generate consistent names and tags for resources. Use terraform-null-label
to implement a strict naming convention.
A label follows the following convention: {namespace}-{environment}-{stage}-{name}-{attributes}
. The delimiter (e.g. -
) is configurable.
The label items are all optional. So if you prefer the term stage
to environment
you can exclude environment and the label id
will look like {namespace}-{stage}-{name}-{attributes}
.
If attributes are excluded but stage
and environment
are included, id
will look like {namespace}-{environment}-{stage}-{name}
It's recommended to use one terraform-null-label
module for every unique resource of a given resource type.
For example, if you have 10 instances, there should be 10 different labels.
However, if you have multiple different kinds of resources (e.g. instances, security groups, file systems, and elastic ips), then they can all share the same label assuming they are logically related.
All Cloud Posse modules use this module to ensure resources can be instantiated multiple times within an account and without conflict.
NOTE: The null
refers to the primary Terraform provider used in this module.
Releases of this module from 0.12.0
onward support HCL2
and only work with Terraform 0.12 or newer. Releases prior to this are compatible with earlier versions of terraform like Terraform 0.11.
This project is part of our comprehensive "SweetOps" approach towards DevOps.
It's 100% Open Source and licensed under the APACHE2.
We literally have hundreds of terraform modules that are Open Source and well-maintained. Check them out!
IMPORTANT: The master
branch is used in source
just as an example. In your code, do not pin to master
because there may be breaking changes between releases.
Instead pin to the release tag (e.g. ?ref=tags/x.y.z
) of one of our latest releases.
Cloud Posse Terraform modules share a common context
object that is meant to be passed from module to module.
The context object is a single object that contains all the input values for terraform-null-label
.
However, each input value can also be specified individually by name as a standard Terraform variable,
and the value of those variables, when set to something other than null
, will override the value
in the context object. In order to allow chaining of these objects, where the context object input to one
module is transformed and passed to the next module, all the variables default to null
or empty collections.
The actual default values used when nothing is explicitly set are describe in the documentation below.
For example, the default value of delimiter
is shown as null
, but if you leave it set to null,
terraform-null-label
will actually use the default delimiter -
(hyphen).
A non-obvious but intentional consequence of this design is that once a module sets a non-default value, future modules in the chain cannot reset the value back to the original default. Insted, the new setting becomes the new default for downstream modules. Also, collections are not overwritten, they are merged, so once a tag is added, it will remain in the tag set and cannot be removed, although its value can be overwritten.
module "eg_prod_bastion_label" {
source = "git::https://github.com/cloudposse/terraform-null-label.git?ref=master"
namespace = "eg"
stage = "prod"
name = "bastion"
attributes = ["public"]
delimiter = "-"
tags = {
"BusinessUnit" = "XYZ",
"Snapshot" = "true"
}
}
This will create an id
with the value of eg-prod-bastion-public
because when generating id
, the default order is namespace
, environment
, stage
, name
, attributes
(you can override it by using the label_order
variable, see Advanced Example 3).
Now reference the label when creating an instance:
resource "aws_instance" "eg_prod_bastion_public" {
instance_type = "t1.micro"
tags = module.eg_prod_bastion_label.tags
}
Or define a security group:
resource "aws_security_group" "eg_prod_bastion_public" {
vpc_id = var.vpc_id
name = module.eg_prod_bastion_label.id
tags = module.eg_prod_bastion_label.tags
egress {
from_port = 0
to_port = 0
protocol = "-1"
cidr_blocks = ["0.0.0.0/0"]
}
}
Here is a more complex example with two instances using two different labels. Note how efficiently the tags are defined for both the instance and the security group.
Click to show
module "eg_prod_bastion_abc_label" {
source = "git::https://github.com/cloudposse/terraform-null-label.git?ref=master"
namespace = "eg"
stage = "prod"
name = "bastion"
attributes = ["abc"]
delimiter = "-"
tags = {
"BusinessUnit" = "XYZ",
"Snapshot" = "true"
}
}
resource "aws_security_group" "eg_prod_bastion_abc" {
name = module.eg_prod_bastion_abc_label.id
tags = module.eg_prod_bastion_abc_label.tags
ingress {
from_port = 22
to_port = 22
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
}
resource "aws_instance" "eg_prod_bastion_abc" {
instance_type = "t1.micro"
tags = module.eg_prod_bastion_abc_label.tags
vpc_security_group_ids = [aws_security_group.eg_prod_bastion_abc.id]
}
module "eg_prod_bastion_xyz_label" {
source = "git::https://github.com/cloudposse/terraform-null-label.git?ref=master"
namespace = "eg"
stage = "prod"
name = "bastion"
attributes = ["xyz"]
delimiter = "-"
tags = {
"BusinessUnit" = "XYZ",
"Snapshot" = "true"
}
}
resource "aws_security_group" "eg_prod_bastion_xyz" {
name = module.eg_prod_bastion_xyz_label.id
tags = module.eg_prod_bastion_xyz_label.tags
ingress {
from_port = 22
to_port = 22
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
}
resource "aws_instance" "eg_prod_bastion_xyz" {
instance_type = "t1.micro"
tags = module.eg_prod_bastion_xyz_label.tags
vpc_security_group_ids = [aws_security_group.eg_prod_bastion_xyz.id]
}
Here is a more complex example with an autoscaling group that has a different tagging schema than other resources and requires its tags to be in this format, which this module can generate:
Click to show
tags = [
{
key = Name,
propagate_at_launch = 1,
value = namespace-stage-name
},
{
key = Namespace,
propagate_at_launch = 1,
value = namespace
},
{
key = Stage,
propagate_at_launch = 1,
value = stage
}
]
Autoscaling group using propagating tagging below (full example: autoscalinggroup)
################################
# terraform-null-label example #
################################
module "label" {
source = "../../"
namespace = "cp"
stage = "prod"
name = "app"
tags = {
BusinessUnit = "Finance"
ManagedBy = "Terraform"
}
additional_tag_map = {
propagate_at_launch = "true"
}
}
#######################
# Launch template #
#######################
resource "aws_launch_template" "default" {
# terraform-null-label example used here: Set template name prefix
name_prefix = "${module.label.id}-"
image_id = data.aws_ami.amazon_linux.id
instance_type = "t2.micro"
instance_initiated_shutdown_behavior = "terminate"
vpc_security_group_ids = [data.aws_security_group.default.id]
monitoring {
enabled = false
}
# terraform-null-label example used here: Set tags on volumes
tag_specifications {
resource_type = "volume"
tags = module.label.tags
}
}
######################
# Autoscaling group #
######################
resource "aws_autoscaling_group" "default" {
# terraform-null-label example used here: Set ASG name prefix
name_prefix = "${module.label.id}-"
vpc_zone_identifier = data.aws_subnet_ids.all.ids
max_size = "1"
min_size = "1"
desired_capacity = "1"
launch_template = {
id = "aws_launch_template.default.id
version = "$$Latest"
}
# terraform-null-label example used here: Set tags on ASG and EC2 Servers
tags = module.label.tags_as_list_of_maps
}
See complete example for even more examples.
This example shows how you can pass the context
output of one label module to the next label_module,
allowing you to create one label that has the base set of values, and then creating every extra label
as a derivative of that.
Click to show
module "label1" {
source = "git::https://github.com/cloudposse/terraform-null-label.git?ref=master"
namespace = "CloudPosse"
environment = "UAT"
stage = "build"
name = "Winston Churchroom"
attributes = ["fire", "water", "earth", "air"]
delimiter = "-"
label_order = ["name", "environment", "stage", "attributes"]
tags = {
"City" = "Dublin"
"Environment" = "Private"
}
}
module "label2" {
source = "git::https://github.com/cloudposse/terraform-null-label.git?ref=master"
context = module.label1.context
name = "Charlie"
stage = "test"
delimiter = "+"
tags = {
"City" = "London"
"Environment" = "Public"
}
}
module "label3" {
source = "git::https://github.com/cloudposse/terraform-null-label.git?ref=master"
name = "Starfish"
stage = "release"
context = module.label1.context
delimiter = "."
tags = {
"Eat" = "Carrot"
"Animal" = "Rabbit"
}
}
This creates label outputs like this:
label1 = {
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "-"
"id" = "winstonchurchroom-uat-build-fire-water-earth-air"
"name" = "winstonchurchroom"
"namespace" = "cloudposse"
"stage" = "build"
}
label1_context = {
"additional_tag_map" = {}
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "-"
"enabled" = true
"environment" = "UAT"
"label_order" = [
"name",
"environment",
"stage",
"attributes",
]
"name" = "Winston Churchroom"
"namespace" = "CloudPosse"
"stage" = "build"
"tags" = {
"City" = "Dublin"
"Environment" = "Private"
}
}
label1_normalized_context = {
"additional_tag_map" = {}
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "-"
"enabled" = true
"environment" = "uat"
"id_length_limit" = 0
"label_order" = [
"name",
"environment",
"stage",
"attributes",
]
"name" = "winstonchurchroom"
"namespace" = "cloudposse"
"regex_replace_chars" = "/[^-a-zA-Z0-9]/"
"stage" = "build"
"tags" = {
"Attributes" = "fire-water-earth-air"
"City" = "Dublin"
"Environment" = "Private"
"Name" = "winstonchurchroom-uat-build-fire-water-earth-air"
"Namespace" = "cloudposse"
"Stage" = "build"
}
}
label1_tags = {
"Attributes" = "fire-water-earth-air"
"City" = "Dublin"
"Environment" = "Private"
"Name" = "winstonchurchroom-uat-build-fire-water-earth-air"
"Namespace" = "cloudposse"
"Stage" = "build"
}
label2 = {
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "+"
"id" = "charlie+uat+test+fire+water+earth+air"
"name" = "charlie"
"namespace" = "cloudposse"
"stage" = "test"
}
label2_context = {
"additional_tag_map" = {
"additional_tag" = "yes"
"propagate_at_launch" = "true"
}
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "+"
"enabled" = true
"environment" = "UAT"
"label_order" = [
"name",
"environment",
"stage",
"attributes",
]
"name" = "Charlie"
"namespace" = "CloudPosse"
"regex_replace_chars" = "/[^a-zA-Z0-9-+]/"
"stage" = "test"
"tags" = {
"City" = "London"
"Environment" = "Public"
}
}
label2_tags = {
"Attributes" = "fire+water+earth+air"
"City" = "London"
"Environment" = "Public"
"Name" = "charlie+uat+test+fire+water+earth+air"
"Namespace" = "cloudposse"
"Stage" = "test"
}
label2_tags_as_list_of_maps = [
{
"additional_tag" = "yes"
"key" = "Attributes"
"propagate_at_launch" = "true"
"value" = "fire+water+earth+air"
},
{
"additional_tag" = "yes"
"key" = "City"
"propagate_at_launch" = "true"
"value" = "London"
},
{
"additional_tag" = "yes"
"key" = "Environment"
"propagate_at_launch" = "true"
"value" = "Public"
},
{
"additional_tag" = "yes"
"key" = "Name"
"propagate_at_launch" = "true"
"value" = "charlie+uat+test+fire+water+earth+air"
},
{
"additional_tag" = "yes"
"key" = "Namespace"
"propagate_at_launch" = "true"
"value" = "cloudposse"
},
{
"additional_tag" = "yes"
"key" = "Stage"
"propagate_at_launch" = "true"
"value" = "test"
},
]
label3 = {
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "."
"id" = "starfish.uat.release.fire.water.earth.air"
"name" = "starfish"
"namespace" = "cloudposse"
"stage" = "release"
}
label3_context = {
"additional_tag_map" = {}
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "."
"enabled" = true
"environment" = "UAT"
"label_order" = [
"name",
"environment",
"stage",
"attributes",
]
"name" = "Starfish"
"namespace" = "CloudPosse"
"regex_replace_chars" = "/[^-a-zA-Z0-9.]/"
"stage" = "release"
"tags" = {
"Animal" = "Rabbit"
"City" = "Dublin"
"Eat" = "Carrot"
"Environment" = "Private"
}
}
label3_normalized_context = {
"additional_tag_map" = {}
"attributes" = [
"fire",
"water",
"earth",
"air",
]
"delimiter" = "."
"enabled" = true
"environment" = "uat"
"id_length_limit" = 0
"label_order" = [
"name",
"environment",
"stage",
"attributes",
]
"name" = "starfish"
"namespace" = "cloudposse"
"regex_replace_chars" = "/[^-a-zA-Z0-9.]/"
"stage" = "release"
"tags" = {
"Animal" = "Rabbit"
"Attributes" = "fire.water.earth.air"
"City" = "Dublin"
"Eat" = "Carrot"
"Environment" = "Private"
"Name" = "starfish.uat.release.fire.water.earth.air"
"Namespace" = "cloudposse"
"Stage" = "release"
}
}
label3_tags = {
"Animal" = "Rabbit"
"Attributes" = "fire.water.earth.air"
"City" = "Dublin"
"Eat" = "Carrot"
"Environment" = "Private"
"Name" = "starfish.uat.release.fire.water.earth.air"
"Namespace" = "cloudposse"
"Stage" = "release"
}
Available targets:
help Help screen
help/all Display help for all targets
help/short This help short screen
lint Lint terraform code
Name | Version |
---|---|
terraform | >= 0.12.0 |
No provider.
Name | Description | Type | Default | Required |
---|---|---|---|---|
additional_tag_map | Additional tags for appending to tags_as_list_of_maps. Not added to tags . |
map(string) |
{} |
no |
attributes | Additional attributes (e.g. 1 ) |
list(string) |
[] |
no |
context | Single object for setting entire context at once. See description of individual variables for details. Leave string and numeric variables as null to use default value.Individual variable settings (non-null) override settings in context object, except for attributes, tags, and additional_tag_map, which are merged. |
object({ |
{ |
no |
delimiter | Delimiter to be used between namespace , environment , stage , name and attributes .Defaults to - (hyphen). Set to "" to use no delimiter at all. |
string |
null |
no |
enabled | Set to false to prevent the module from creating any resources | bool |
null |
no |
environment | Environment, e.g. 'uw2', 'us-west-2', OR 'prod', 'staging', 'dev', 'UAT' | string |
null |
no |
id_length_limit | Limit id to this many characters.Set to 0 for unlimited length.Set to null for default, which is 0 .Does not affect id_full . |
number |
null |
no |
label_order | The naming order of the id output and Name tag. Defaults to ["namespace", "environment", "stage", "name", "attributes"]. You can omit any of the 5 elements, but at least one must be present. |
list(string) |
null |
no |
name | Solution name, e.g. 'app' or 'jenkins' | string |
null |
no |
namespace | Namespace, which could be your organization name or abbreviation, e.g. 'eg' or 'cp' | string |
null |
no |
regex_replace_chars | Regex to replace chars with empty string in namespace , environment , stage and name .If not set, "/[^a-zA-Z0-9-]/" is used to remove all characters other than hyphens, letters and digits. |
string |
null |
no |
stage | Stage, e.g. 'prod', 'staging', 'dev', OR 'source', 'build', 'test', 'deploy', 'release' | string |
null |
no |
tags | Additional tags (e.g. map('BusinessUnit','XYZ') |
map(string) |
{} |
no |
Name | Description |
---|---|
additional_tag_map | The merged additional_tag_map |
attributes | List of attributes |
context | Merged but otherwise unmodified input to this module, to be used as context input to other modules. Note: this version will have null values as defaults, not the values actually used as defaults. |
delimiter | Delimiter between namespace , environment , stage , name and attributes |
enabled | True if module is enabled, false otherwise |
environment | Normalized environment |
id | Disambiguated ID restricted to id_length_limit characters in total |
id_full | Disambiguated ID not restricted in length |
id_length_limit | The id_length_limit actually used to create the ID, with 0 meaning unlimited |
label_order | The naming order actually used to create the ID |
name | Normalized name |
namespace | Normalized namespace |
normalized_context | Normalized context of this module |
regex_replace_chars | The regex_replace_chars actually used to create the ID |
stage | Normalized stage |
tags | Normalized Tag map |
tags_as_list_of_maps | Additional tags as a list of maps, which can be used in several AWS resources |
Like this project? Please give it a ★ on our GitHub! (it helps us a lot)
Are you using this project or any of our other projects? Consider leaving a testimonial. =)
Check out these related projects.
- terraform-terraform-label - Terraform Module to define a consistent naming convention by (namespace, environment, stage, name, [attributes])
Got a question? We got answers.
File a GitHub issue, send us an email or join our Slack Community.
We are a DevOps Accelerator. We'll help you build your cloud infrastructure from the ground up so you can own it. Then we'll show you how to operate it and stick around for as long as you need us.
Work directly with our team of DevOps experts via email, slack, and video conferencing.
We deliver 10x the value for a fraction of the cost of a full-time engineer. Our track record is not even funny. If you want things done right and you need it done FAST, then we're your best bet.
- Reference Architecture. You'll get everything you need from the ground up built using 100% infrastructure as code.
- Release Engineering. You'll have end-to-end CI/CD with unlimited staging environments.
- Site Reliability Engineering. You'll have total visibility into your apps and microservices.
- Security Baseline. You'll have built-in governance with accountability and audit logs for all changes.
- GitOps. You'll be able to operate your infrastructure via Pull Requests.
- Training. You'll receive hands-on training so your team can operate what we build.
- Questions. You'll have a direct line of communication between our teams via a Shared Slack channel.
- Troubleshooting. You'll get help to triage when things aren't working.
- Code Reviews. You'll receive constructive feedback on Pull Requests.
- Bug Fixes. We'll rapidly work with you to fix any bugs in our projects.
Join our Open Source Community on Slack. It's FREE for everyone! Our "SweetOps" community is where you get to talk with others who share a similar vision for how to rollout and manage infrastructure. This is the best place to talk shop, ask questions, solicit feedback, and work together as a community to build totally sweet infrastructure.
Participate in our Discourse Forums. Here you'll find answers to commonly asked questions. Most questions will be related to the enormous number of projects we support on our GitHub. Come here to collaborate on answers, find solutions, and get ideas about the products and services we value. It only takes a minute to get started! Just sign in with SSO using your GitHub account.
Sign up for our newsletter that covers everything on our technology radar. Receive updates on what we're up to on GitHub as well as awesome new projects we discover.
Join us every Wednesday via Zoom for our weekly "Lunch & Learn" sessions. It's FREE for everyone!
Please use the issue tracker to report any bugs or file feature requests.
If you are interested in being a contributor and want to get involved in developing this project or help out with our other projects, we would love to hear from you! Shoot us an email.
In general, PRs are welcome. We follow the typical "fork-and-pull" Git workflow.
- Fork the repo on GitHub
- Clone the project to your own machine
- Commit changes to your own branch
- Push your work back up to your fork
- Submit a Pull Request so that we can review your changes
NOTE: Be sure to merge the latest changes from "upstream" before making a pull request!
Copyright © 2017-2020 Cloud Posse, LLC
See LICENSE for full details.
Licensed to the Apache Software Foundation (ASF) under one
or more contributor license agreements. See the NOTICE file
distributed with this work for additional information
regarding copyright ownership. The ASF licenses this file
to you under the Apache License, Version 2.0 (the
"License"); you may not use this file except in compliance
with the License. You may obtain a copy of the License at
https://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing,
software distributed under the License is distributed on an
"AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
KIND, either express or implied. See the License for the
specific language governing permissions and limitations
under the License.
All other trademarks referenced herein are the property of their respective owners.
This project is maintained and funded by Cloud Posse, LLC. Like it? Please let us know by leaving a testimonial!
We're a DevOps Professional Services company based in Los Angeles, CA. We ❤️ Open Source Software.
We offer paid support on all of our projects.
Check out our other projects, follow us on twitter, apply for a job, or hire us to help with your cloud strategy and implementation.
Erik Osterman |
Andriy Knysh |
Igor Rodionov |
Sergey Vasilyev |
Michael Pereira |
Jamie Nelson |
Vladimir |
Daren Desjardins |
Maarten van der Hoef |
Adam Tibbing |
---|