Fix pick up melee loop about left4bots HOT 5 OPEN

//delete some thing, need test more.
//tracemask_pickups = 16395; //CONTENTS_SOLID | CONTENTS_MOVEABLE | CONTENTS_WINDOW | CONTENTS_GRATE
::Left4Bots.CanTraceToPickup <- function (bot, item)
{
	//local mask = 0x1 | 0x8 | 0x40 | 0x2000 | 0x4000  | 0x8000000; // CONTENTS_SOLID | CONTENTS_GRATE | CONTENTS_BLOCKLOS | CONTENTS_IGNORE_NODRAW_OPAQUE | CONTENTS_MOVEABLE | CONTENTS_DETAIL
	local traceTable = { start = bot.EyePosition(), end = item.GetOrigin(), ignore = bot, mask = Settings.tracemask_pickups };

	TraceLine(traceTable);

	//printl("fraction: " + traceTable.fraction);
	//DebugDrawCircle(traceTable.pos, Vector(0, 0, 255), 255, 10, true, 0.1);

	return (traceTable.fraction > 0.98 || !traceTable.hit || !traceTable.enthit || traceTable.enthit == item || traceTable.enthit.GetClassname() == "prop_health_cabinet");
}

::Left4Bots.LoadWeaponPreferences <- function (survivor, scope)
{
	// WeapPref array has one sub-array for each inventory slot
	// Each sub-array contains the weapons from the highest to the lowest priority one for that inventory slot
	scope.WeapPref <- [[], [], [], [], []];
	
	// WeapNoPref array contains a flag for each inventory slot
	// The flag indicates whether the priority of the weapons in WeapPref for that slot must be ignored
	scope.WeapNoPref <- [false, false, false, false, false];

	if (!survivor || !survivor.IsValid() || !scope)
		return;

	//Logger.Debug("LoadWeaponPreferences - survivor: " + survivor.GetPlayerName());

	// TODO: do this with the character id instead
	local filename = GetCharacterDisplayName(survivor);
	if (filename == null || filename == "")
		filename = survivor.GetPlayerName(); // Apparently the L4D1 survivors in The Passing 3 don't have a CharacterDisplayName
	filename = Settings.file_weapons_prefix + filename.tolower() + ".txt";
	local lines = Left4Utils.FileToStringList(filename);
	if (!lines)
		return;

	local c = 0;
	for (local i = 0; i < lines.len(); i++)
	{
		local line = Left4Utils.StripComments(lines[i]);
		if (line != "")
		{
			local weaps = split(line, ",");
			for (local x = 0; x < weaps.len(); x++)
			{
				//delete space characters which cause bug
				local wp = strip(weaps[x]);
				
				if (x == 0 && wp == "*")
					scope.WeapNoPref[i] = true;
				else
				{
					local id = Left4Utils.GetWeaponIdByName(wp);

					//Logger.Debug("LoadWeaponPreferences - i: " + i + " - w: " + wp + " - id: " + id);

					if (id > Left4Utils.WeaponId.none && id != Left4Utils.MeleeWeaponId.none && id != Left4Utils.UpgradeWeaponId.none)
					{
						scope.WeapPref[i].append(id); // valid weapon
						c++;
					}
				}
			}
		}
	}

	Logger.Debug("LoadWeaponPreferences - Loaded " + c + " preferences for survivor: " + survivor.GetPlayerName() + " from file: " + filename);
}