关于同步到Maven Central about gradle-publish HOT 2 CLOSED

apply plugin: 'maven'
apply plugin: 'signing'
group = PROJ_GROUP
version = PROJ_VERSION
ext {
    UsingSonatype = hasProperty('UsingSonatype')
    isReleaseVersion = !version.endsWith("-SNAPSHOT")
// Defind in ~/.gradle/gradle.properties
    ReleaseUrl = UsingSonatype ? SONATYPE_RELEASE_URL : LOCAL_RELEASE_URL
    SnapshotUrl = UsingSonatype ? SONATYPE_SNAPSHOT_URL : LOCAL_SNAPSHOT_URL
    Username = UsingSonatype ? SONATYPE_USER : LOCAL_USERNAME
    Password = UsingSonatype ? SONATYPE_PASS : LOCAL_PASSWORD
    publishAar = hasProperty('aar') ? true : false
}
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

task sourcesJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier = 'sources'
}

task javadoc(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += configurations.compile
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

javadoc {
    options{
        encoding "UTF-8"
        charSet 'UTF-8'
        author true
        version true
        links "http://docs.oracle.com/javase/7/docs/api/"
        links "http://androiddoc.qiniudn.com/reference/"
        title PROJ_NAME
    }
}

artifacts {
    archives javadocJar
    archives sourcesJar
}
afterEvaluate { project ->
    artifacts {
        archives packageReleaseJar
    }
    signing {
        required { isReleaseVersion && gradle.taskGraph.hasTask("uploadArchives") }
        sign configurations.archives
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                pom.groupId = PROJ_GROUP
                pom.artifactId = PROJ_ARTIFACT_ID
                pom.version = version
                repository(url: ReleaseUrl) {
                    authentication(userName: Username, password: Password)
                }
                snapshotRepository(url: SnapshotUrl) {
                    authentication(userName: Username, password: Password)
                }
                pom.project {
                    inceptionYear PROJ_INCEPTION_YEAR
                    name PROJ_NAME
                    packaging publishAar ? 'aar' : 'jar'
                    description PROJ_DESCRIPTION
                    url PROJ_URL
                    scm {
                        url SCM_URL
                        connection SCM_CONNECTION
                        developerConnection SCM_DEV_CONNECTION
                    }
                    licenses {
                        license {
                            name LICENSE_NAME
                            url LICENSE_URL
                            distribution LICENSE_DISTRIBUTION
                        }
                    }
                    developers {
                        developer {
                            id DEVELOPER_ID
                            name DEVELOPER_NAME
                        }
                    }
                }
            }
        }
    }
}

PROJ_GROUP=
PROJ_VERSION=
PROJ_NAME=
PROJ_DESCRIPTION=ARM  SDK
PROJ_ARTIFACT_ID=
PROJ_INCEPTION_YEAR=2015
PROJ_URL=

SCM_URL=
SCM_CONNECTION=
SCM_DEV_CONNECTION=

LICENSE_NAME=The Apache Software License, Version 2.0
LICENSE_URL=http://www.apache.org/licenses/LICENSE-2.0.txt
LICENSE_DISTRIBUTION=repo

DEVELOPER_ID=
DEVELOPER_NAME=
DEVELOPER_EMAIL=

SONATYPE_RELEASE_URL=https://oss.sonatype.org/service/local/staging/deploy/maven2
SONATYPE_SNAPSHOT_URL=https://oss.sonatype.org/content/repositories/snapshots
SONATYPE_NEXUS_USERNAME=username for sonatype
SONATYPE_NEXUS_PASSWORD=password for sonatype

LOCAL_RELEASE_URL=私服
LOCAL_SNAPSHOT_URL=私服
LOCAL_USERNAME=私服账号
LOCAL_PASSWORD=私服密码