Plugin class not found after just updating kotlin dependencies about gradle-sonar-packaging-plugin HOT 4 OPEN

buildscript {

	repositories {
		mavenCentral()
		mavenLocal()
		jcenter()
		maven { url "http://dl.bintray.com/jetbrains/spek" }
		maven { url "https://plugins.gradle.org/m2" }
	}

	dependencies {
		classpath "org.junit.platform:junit-platform-gradle-plugin:$junitPlatformVersion"
		classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
	}
}

plugins {
	id "com.iadams.sonar-packaging" version "1.0-RC1"
	id "org.sonarqube" version "2.5"
	id "io.gitlab.arturbosch.detekt" version "1.0.0.RC4-3"
}

apply plugin: 'kotlin'
apply plugin: 'jacoco'

group 'io.gitlab.arturbosch.detekt'
version = "$detektSonarVersion"

repositories {
	jcenter()
	mavenLocal()
	mavenCentral()
}

dependencies {
	compile "io.gitlab.arturbosch.detekt:detekt-core:$detektVersion"
	compile "io.gitlab.arturbosch.detekt:detekt-formatting:$detektVersion"
	compile "io.gitlab.arturbosch.detekt:detekt-rules:$detektVersion"
	compileOnly "org.sonarsource.sonarqube:sonar-plugin-api:$sonarVersion"
	compile "org.sonarsource.java:java-jacoco:4.11.0.10660"

	testCompile "junit:junit:4.12"
	testCompile "com.nhaarman:mockito-kotlin-kt1.1:$mockitoKotlinVersion"
	testCompile "org.junit.jupiter:junit-jupiter-api:$junitEngineVersion"
	testCompile "org.jetbrains.kotlin:kotlin-test:$kotlinVersion"
	testCompile "org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion"
	testCompile "org.assertj:assertj-core:$assertjVersion"
	testCompile "org.jetbrains.spek:spek-api:$spekVersion"
	testCompile "org.jetbrains.spek:spek-subject-extension:$spekVersion"
	testCompile "org.junit.jupiter:junit-jupiter-engine:$junitEngineVersion"
	testRuntime "org.junit.platform:junit-platform-launcher:$junitPlatformVersion"
	testRuntime "org.junit.platform:junit-platform-console:$junitPlatformVersion"
	testRuntime "org.jetbrains.spek:spek-junit-platform-engine:$spekVersion"
}

sourceSets {
	main.java.srcDirs += 'src/main/kotlin'
}


jacocoTestReport {
	dependsOn test
	reports {
		xml.enabled = true
		html.enabled = true
	}
}

check.dependsOn jacocoTestReport

def USER_HOME = System.getProperty("user.home")

sonarPackaging {
	serverUrl = 'http://localhost:9000'
	pluginDir = "$USER_HOME/Downloads/sonarqube-6.4/extensions/plugins"
	pluginKey = 'kotlin'
	pluginClass = 'io.gitlab.arturbosch.detekt.sonar.DetektPlugin'
	pluginName = 'Kotlin'
	pluginDescription = 'Work in progress kotlin sonar plugin.'
	pluginParent = null
	pluginLicense = 'APACHE 2.0'
	requirePlugins = null
	pluginUrl = 'http://github.com/arturbosch/sonar-kotlin'
	pluginIssueTrackerUrl = 'http://github.com/arturbosch/sonar-kotlin/issues'
	pluginTermsConditionsUrl = 'http://github.com/arturbosch/sonar-kotlin'
	pluginSourceUrl = 'http://github.com/arturbosch/sonar-kotlin'
	pluginDevelopers = 'Artur Bosch'
	skipDependenciesPackaging = false
	useChildFirstClassLoader = false
	basePlugin = ''
	sonarQubeMinVersion = '5.6'
}

detekt {
	version = usedDetektGradlePlugin
	profile("main") {
		input = "$project.projectDir"
		filters = '.*/test/.*, .*/resources/.*, .*/build/.*'
		baseline = "$project.projectDir/reports/baseline.xml"
	}
	idea {
		path = "$USER_HOME/.idea"
		codeStyleScheme = "$USER_HOME/.idea/idea-code-style.xml"
		inspectionsProfile = "$USER_HOME/.idea/inspect.xml"
		report = "$project.projectDir/reports"
		mask = "*.kt,"
	}
}
compileKotlin {
	kotlinOptions {
		jvmTarget = "1.8"
	}
}
compileTestKotlin {
	kotlinOptions {
		jvmTarget = "1.8"
	}
}