example: usage with gradle5/kotlin dsl about gradle-swagger-generator-plugin HOT 6 OPEN

plugins {
    // ...
    id("org.hidetake.swagger.generator") version "2.18.1"
}

// ...

dependencies {
    swaggerCodegen("io.swagger.codegen.v3:swagger-codegen-cli:3.0.8")
   // ... other Swagger dependencies like annotations
}

// ...

swaggerSources {
    // Gradle recommends `register` over `create` to avoid eagerly creating/configuring items.
    register("petstore") {
        // Part of the "petstore" SwaggerSource
        // Need to save a reference of it here because the `this` scope changes below.
        val validationTask = validation

        setInputFile(file("petstore-swagger.json"))

        // The method signiature is `code(@DelegatesTo(GenerateSwaggerCode) Closure closure)`
        // So best to use `delegateClosureOf<GenerateSwaggerCode>`
        // https://docs.gradle.org/current/userguide/kotlin_dsl.html#groovy_closures_from_kotlin
        code(delegateClosureOf<GenerateSwaggerCode> {
            language = "spring"
            components = listOf("models")
            dependsOn(validationTask)
        })
    }
}

tasks.named("compileJava").configure {
    dependsOn(tasks.named("generateSwaggerCode"))
}

sourceSets {
    val main by getting
    val petstore by swaggerSources.getting
    main.java.srcDir("${petstore.code.outputDir}/src/main/java")
}