Where should I add e.g. Hilt Android and AndroidX Navigation Safe Args Gradle Plugins? about kotlin-android-template HOT 13 OPEN

pluginManagement {
    resolutionStrategy {
        eachPlugin {
            when (requested.id.id) {
                "androidx.navigation.safeargs.kotlin" -> {
                    useModule("androidx.navigation:navigation-safe-args-gradle-plugin:${requested.version}")
                }
                "dagger.hilt.android.plugin" -> {
                    useModule("com.google.dagger:hilt-android-gradle-plugin:${requested.version}")
                }
            }
        }
    }
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }
}

plugins {
    `android-app` apply false
    `android-library` apply false
    `kotlin-android` apply false
    `kotlin-kapt` apply false
    `kotlin-serialization` version PluginVersions.Kotlin apply false
    `kotlin-parcelize` apply false
    `hilt-android` apply false
    `androidx-navigation-safe-args` apply false
}

allprojects {
    group = ""
    repositories {
        google()
        mavenCentral()
    }
}

plugins {
    `kotlin-dsl`
}

repositories {
    google()
    mavenCentral()
}

dependencies {
    implementation(group = "com.android.tools.build", name = "gradle", version = "7.0.2")
    implementation(kotlin(module = "gradle-plugin", version = "1.5.30"))
    implementation(group = "com.google.dagger", name = "hilt-android-gradle-plugin", version = "2.38.1")
    implementation(group = "androidx.navigation", name = "navigation-safe-args-gradle-plugin", version = "2.3.5")
}

plugins {
    `android-app`
    `kotlin-android`
    `kotlin-kapt`
    `kotlin-serialization`
    `kotlin-parcelize`
    `hilt-android`
    `androidx-navigation-safe-args`
}

android {
    compileSdk = Android.CompileSdkVersion
    buildToolsVersion = Android.BuildToolsVersion
    ndkVersion = Android.NdkVersion

    defaultConfig {
        applicationId = ""
        minSdk = Android.MinSdk
        targetSdk = Android.TargetSdk
        versionCode = Android.VersionCode
        versionName = Android.VersionName
    }

    signingConfigs {
        register("release") {
            enableV1Signing = true
            enableV2Signing = true
            enableV3Signing = true
            enableV4Signing = true
        }
    }

    buildTypes {
        debug {
            applicationIdSuffix = ".debug"
        }
        release {
            isMinifyEnabled = true
            isShrinkResources = true
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro"
            )
            ndk {
                debugSymbolLevel = "FULL"
            }
        }
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }

    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_11.toString()
        freeCompilerArgs = listOf("-Xopt-in=kotlin.RequiresOptIn")
    }

    buildFeatures {
        viewBinding = true
    }

    lint {
        isCheckDependencies = true
    }
}

dependencies {
    implementation(libs.androidx.hilt.work)
    kapt(libs.androidx.hilt.compiler)
    implementation(libs.hilt.android)
    kapt(libs.hilt.compiler)
}

kapt {
    correctErrorTypes = true
}

hilt {
    enableAggregatingTask = true
}