Figure out how to do read-only Programmable property access about codecombat HOT 4 CLOSED

    # ...
    inner = aether.createFunction()
    outer = (args...) ->
      userContext = @createUserContext()
      try
        result = inner.apply userContext, args
      catch error
        @handleProgrammingError error, methodName
        @replaceMethodCode methodName, null  # no-op when this method is called
        result = null
      @updateFromUserContext userContext  # Apply any viable changes they actually made in the context to the real objects
      return result

  # ...

  createUserContext: ->
    ctx = {}
    thang = @
    props = _.union @programmableProperties, @extraProgrammableProperties
    for prop in props
      value = @[prop]
      v2 = value
      if _.isFunction value
        do (prop, v2, thang) ->
          value = =>
            result = v2.apply thang, arguments  # Functions use original thangs
            # But then the context also needs to get updated with any new state that happened as a result of the function call!
            # (this.setTarget(obj) gives thang.target == obj, but not ctx.target == obj)
            for anotherProp in props
              newValue = thang[anotherProp]
              unless _.isFunction newValue
                ctx[anotherProp] = newValue
            result
      # Object.defineProperty doesn't work in web worker in my test, no idea why; works in Chrome console
      #Object.defineProperty ctx, prop, {value: value, writable: false, enumerable: true}
      # It does seem to work in IE 9 and 10 but not 11 and then make it so the property isn't updatable.
      # Or something. Man, that was a terrible bug. An endless ocean of blood was spilt here.
      ctx[prop] = value  # so doing this instbead
    for prop in @userCreatedProperties
      ctx[prop] = @[prop]
    ctx

  updateFromUserContext: (ctx) ->
    for own prop, value of ctx
      if (prop in @programmableProperties) or (prop in @extraProgrammableProperties) then continue
      unless prop in @userCreatedProperties
        if @[prop]? then continue
        @userCreatedProperties.push prop
      if prop in @userCreatedProperties
        @[prop] = value