default values not being used in mapping when explicitly calling new on Object about pkl HOT 4 OPEN

  [8088] {
    port = 8088
    targetPort = port
  }

class MyThing {
  favoriteColors: Listing<String> = new {
    "blue"
  }
}

directAmend: MyThing = new { // this `new` makes a MyThing and amends the class's defaults
  favoriteColors { // this amend adds to the parent (the new MyThing) and its defaults
    "red"
  }
}

directAmendAgain: MyThing = (directAmend) { // this amends `directAmend`
  favoriteColors { // this amend adds to the parent (`directAmend`) and its value
    "yellow"
  }
}

defaultAmend: MyThing = (directAmend) {
  favoriteColors = new { // this amends the default value of `MyThing`'s `favoriteColors`
    "yellow"
  }
}

noAmend: MyThing = (directAmend) {
  favoriteColors = new Listing<String> { // this amends the default value of `Listing<String> ` (which is empty)
    "yellow"
  }
}

directAmend {
  favoriteColors { // the class's defaults, adding "red"
    "blue"
    "red"
  }
}
directAmendAgain {
  favoriteColors { // directAmend's value, adding "yellow"
    "blue"
    "red"
    "yellow"
  }
}
defaultAmend {
  favoriteColors { // the class's defaults, adding "yellow"
    "blue"
    "yellow"
  }
}
noAmend {
  favoriteColors { // an empty listing, adding "yellow"
    "yellow"
  }
}

someThings: Listing<MyThing> = new {
  default {
    favoriteColors { // this amends the default value of `MyThing`'s `favoriteColors`
      "green"
    }
  }

  new { // this amends `someThings`'s `default`
    favoriteColors {
      "purple"
    }
  }
  new MyThing { // this `new` makes a MyThing and amends the class's defaults (ignoring the Listing's `default`)
    favoriteColors {
      "purple"
    }
  }
  new { // this amends `someThings`'s `default`
    favoriteColors = new { // but this amend's the class's default value (ignoring the Listing's `default`)
      "purple"
    }
  }
  new MyThing { // this `new` makes a MyThing and amends the class's defaults (ignoring the Listing's `default`)
    favoriteColors = new { // and this amend's the class's default value
      "purple"
    }
  }
  new { // this amends `someThings`'s `default`
    favoriteColors = new Listing<String> { // but this creates a new empty Listing and amends it
      "purple"
    }
  }
  new MyThing { // this `new` makes a MyThing and amends the class's defaults (ignoring the Listing's `default`)
    favoriteColors = new Listing<String> { // but this creates a new empty Listing and amends it
      "purple"
    }
  }
}

someThings {
  new {
    favoriteColors {
      "blue"
      "green"
      "purple"
    }
  }
  new {
    favoriteColors {
      "blue"
      "purple"
    }
  }
  new {
    favoriteColors {
      "blue"
      "purple"
    }
  }
  new {
    favoriteColors {
      "blue"
      "purple"
    }
  }
  new {
    favoriteColors {
      "purple"
    }
  }
  new {
    favoriteColors {
      "purple"
    }
  }
}

      default { _port ->
        appProtocol = "HTTP"
        name = appProtocol.toLowerCase()
        protocol = "TCP"
        port = _port
        targetPort = port
      }
      [8086] {}
      [8081] {
        name = "debug"
      }