File devParam.dat about zsgx1hacks HOT 13 OPEN

program datcrc;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

procedure BufWriteData(buf:PByte; bufsz, from, sz:Int64; const data:string);
var rb:RawByteString;
begin
  if bufsz<from+sz then raise Exception.Create('Bad data size');
  fillchar(PByte(buf+from)^,sz,0);
  rb:=RawByteString(data);  //Unicode string to 8bit string
  if length(rb)<sz then sz:=length(rb);
  Move(rb[1],PByte(buf+from)^,sz);
end;

//devParam.dat  size 3*4 + 1024 = 1036
// 0x0000   UINT       0x20150910     date ???
// 0x0004   UINT       data crc       data word sum - 32bit sum of 16bit words
// 0x0008   UINT       data size      0x00000400  = 1024
// 0x000C   char(size) data
// ...
// 0x0128   pansichar  SSID
// ...
// 0x0154   pansichar  password
// ...
// 0x01FC   pansichar  username      (admin)???
// ...


procedure UpdateWiFi(const fname,ssid,pass:string);
var fsz,bsz,cnt,i,crc:longint;
  fh:THandle;
  buf:PByte;
const
  CRCPOS    = $0004;
  SIZEPOS   = $0008;
  DATASTART = $000C;
  SSIDPOS   = $0128;
  SSIDSZ    = $20;  // not 100% sure, maybe more
  PASSPOS   = $0154;
  PASSSZ    = $20;  // not 100% sure, maybe more
begin
    fh:=FileOpen(fname, fmOpenReadWrite);
    if (fh> 0) then begin
    try
      fsz:=FileSeek(fh, 0, 2{soFromEnd});
      buf:=AllocMem(fsz);
      try
        FileSeek(fh,0,0{soFromBeginning});
        bsz:=FileRead(fh,buf^,fsz);
        //change data
        BufWriteData(buf,bsz,SSIDPOS,SSIDSZ,ssid);
        BufWriteData(buf,bsz,PASSPOS,PASSSZ,pass);
        //get crc
        cnt:=bsz div 2; //word count
        crc:=0;
        for i := (DATASTART div 2) to cnt do begin
          crc:=crc + (buf[i*2]+buf[i*2+1]*256);
        end;
        //update crc
        //CopyMemory(PByte(buf+CRCPOS),@crc,4);
        Move(crc,PByte(buf+CRCPOS)^,4);
        //update file
        FileSeek(fh,0,0{soFromBeginning});
        if FileWrite(fh,buf^,bsz)=bsz then begin
          writeln('File: '+fname);
          writeln('CRC:  '+IntToHex(crc));
        end;
      finally
        freemem(buf);
      end;
    finally
      FileClose(fh);
    end;
  end else raise Exception.Create('Cannot open file');
end;

var fname:string;
begin
  try
    if ParamStr(1)='' then begin
      writeln('Usage datcrc.exe SSID password [filename]');
      writeln('(filename is optional, if not defined, devParam.dat used)');
      exit;
    end;
    fname:=paramstr(3);
    if fname='' then fname:='devParam.dat';
    UpdateWiFi(fname,ParamStr(1),ParamStr(2));
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.