Interrupts with an ESP32 about adafruit-mcp23017-arduino-library HOT 2 CLOSED

#include <Wire.h>
#include <Adafruit_MCP23017.h>

Adafruit_MCP23017 mcp;

byte ledPin = 8;
byte arduinoIntPin = 25;
volatile boolean awakenByInterrupt = false;
static uint16_t ledState = 0;
byte mcpPinA = 7;


void setup() {

  Serial.begin(9600);
  Serial.println("MCP23007 Interrupt Test");

  pinMode(arduinoIntPin, INPUT);

  mcp.begin();      // use default address 0
  mcp.pinMode(ledPin, OUTPUT);


  mcp.pinMode(mcpPinA, INPUT);
  mcp.pullUp(mcpPinA, HIGH);  // turn on a 100K pullup internally

  mcp.setupInterrupts(true, false, LOW);
  mcp.setupInterruptPin(mcpPinA, FALLING);

  mcp.readGPIOAB();

  attachInterrupt(digitalPinToInterrupt(arduinoIntPin), intCallBack, FALLING);

}

// The int handler will just signal that the int has happen
// we will do the work from the main loop.
void intCallBack() {
  awakenByInterrupt = true;
}

void handleInterrupt() {

  uint8_t pin = mcp.getLastInterruptPin();
  uint8_t val = mcp.getLastInterruptPinValue();

  if ( pin == mcpPinA && val == 0) { //  Test for release - pin pulled high
    if ( ledState ) {
      mcp.digitalWrite(ledPin, LOW);
    } else {
      mcp.digitalWrite(ledPin, HIGH);
    }

    ledState = ! ledState;
  }

  while ( !mcp.digitalRead(mcpPinA));
  // and clean queued INT signal
  cleanInterrupts();
}

void cleanInterrupts() {
  delay(50);
  mcp.readGPIOAB();
  awakenByInterrupt = false;
}

void loop() {
  if (awakenByInterrupt) handleInterrupt();
}